#!/bin/csh -f
set degrees = 90

# Figure out what program we can use
which jpegtran >& /dev/null
if ($status == 0) set has_jpegtran
which convert >& /dev/null
if ($status == 0) set has_convert

if (! ($?has_jpegtran || $?has_convert)) then
  echo "You need either jpegtran or convert in order to use rotateall"
  exit 1
endif

while ($#argv >= 1)
    if ("$argv[1]" == '-left') then
        set degrees = 270
        echo "Rotating left"
    else if ("$argv[1]" == '-right') then
        set degrees = 90
        echo "Rotating right"
    else if ("$argv[1]" == '-180') then
        set degrees = 180
        echo "Rotating right"
    else if ("$argv[1]" =~ -*) then
        echo "Usage: rotate [-left|-right] img ..."
        exit
    else
        echo rotate $argv[1] $degrees
	if (($argv[1] =~ *.jpg || $argv[1] =~ *.JPG) && $?has_jpegtran) then
	  echo "$argv[1] is a jpeg; using jpegtran"
	  jpegtran -rot $degrees -copy all $argv[1] >foo
	else if ($?has_convert) then
          convert -rotate $degrees $argv[1] foo
	endif
        mv foo $argv[1]
    endif
    shift
end

